; Fil: ASC2I.ASM                   Datum: 85-09-18 
; Inskrivet av:  Kristoffer Eriksson 
; Fungerar p} b}de ABC80 och ABC800, och |vriga Z80-burkar. 

;*   L{ser ett med ASCII-siffror skrivet decimalt tal p} adressen HL, vilket 
;*   placeras i DE. L{sning p}g}r tills en icke-siffra p}tr{ffas. 
;*   A f|rst|rs, HL |kas med antalet siffror, DE blir v{rdet. 


            EXTERN ASC2I 

ASC2I:      ld    de,0             ; DE=aktuellt talv{rde. 
LOOP:       ld    a,(hl) 
            sub   "0" 
            ret c                  ; Ej siffra, mindre {n nolla. 
            cp    10 
            ret nc                 ; St|rre {n nia. 
            inc   hl 
            push  hl 
            ld    l,e 
            ld    h,d 
            add   hl,hl            ; x 2 
            add   hl,hl            ; x 4 
            add   hl,de            ; x 5 
            add   hl,hl            ; x 10 
            ld    e,a 
            ld    d,0 
            add   hl,de 
            ex    de,hl            ; Nu har de blivit de x 10 + a 
            pop   hl 
            jr    LOOP